Données ouvertes liées (Linked Open Data)

PSM

John Samuel
CPE Lyon

Année: 2025-2026
Courriel: john.samuel@cpe.fr

Linked Open Data

Linked Open Data

Linked Open Data

1. LOD datasets 2009 (Wikimedia Commons)
2. LOD datasets 2010 (Wikimedia Commons)

Wikidata

Wikidata, lancé en 2012, est un projet collaboratif de la Wikimedia Foundation visant à créer une base de connaissances libre, liée et multilingue. Il sert de source centrale de données pour Wikipédia et d’autres projets Wikimédia.

• Libre et Ouverte : Les données sont accessibles sous licence libre pour encourager leur réutilisation.
• Liée et Structurée : Les informations suivent le modèle RDF et sont interconnectées via des identifiants uniques.
• Collaborative : Des contributeurs du monde entier ajoutent, vérifient et enrichissent les données.
• Multilingue : Wikidata prend en charge des centaines de langues, facilitant l’accès global à la connaissance.

Wikidata

Évolution des sites Wikipédia : passage de plusieurs Wikipédias multilingues séparées à une base de connaissances centralisée (Wikidata) permettant une cohérence et une mise à jour unifiée des données entre langues.

Wikipédia : Articles multilingues

L’Infobox est une composante essentielle des articles Wikipédia. Elle résume, sous une forme structurée, les informations principales sur un sujet donné.

• Contenu de l’Infobox :
  • Informations essentielles : Données clés comme la date de naissance, la localisation ou les caractéristiques principales.
  • Liens pertinents : Souvent connectée à des entités Wikidata pour garantir la cohérence et la mise à jour.

Wikipédia : Articles multilingues

• Objectifs de l’Infobox :
  • Accessibilité rapide : Permet une consultation immédiate des faits essentiels.
  • Uniformité : Garantit une présentation cohérente des informations à travers les articles.
• Évolution dynamique :
  • Mise à jour collaborative : Les Infoboxes peuvent être modifiées collectivement par la communauté.
  • Liens dynamiques avec Wikidata : Les données peuvent être synchronisées automatiquement depuis Wikidata pour maintenir leur exactitude.

Wikipédia : Articles multilingues

Problèmes potentiels

Wikipédia : Articles multilingues

Problèmes potentiels

• Répétitions possibles entre les détails de l’Infobox et le texte principal de l’article.
• Maintenance complexe des Infoboxes à travers les différentes Wikipédias linguistiques.
• Difficulté de mise à jour centralisée et cohérente sans source unique de vérité.

Élément de Wikidata : libellés, descriptions et alias

Chaque élément de Wikidata comprend un libellé (nom principal), une description (brève explication) et des alias (variantes ou synonymes). Ces champs facilitent la recherche et la compréhension des entités dans plusieurs langues.

Élément (item) de Wikidata : Étiquettes et propriétés

Les propriétés décrivent les caractéristiques, relations ou attributs d’un élément (par ex. date de naissance, lieu, profession). Elles permettent une représentation structurée et interconnectée de la connaissance.

Propriétés de Wikidata

Propriétés: Étiquettes et descriptions

Propriétés

Propriétés de l'Infobox de Wikipedia

Identifiant, étiquettes, descriptions et alias

Wikidata: Informations, propriétés, qualifications et références

• Informations de Base :
  • Élément : Représente une entité dans Wikidata (personne, lieu, concept, etc.).
  • Identificateur Unique (QID) : Chaque élément est associé à un identifiant unique.
• Propriétés:
  • Définition : Caractéristiques ou relations spécifiques à un élément.
  • Exemples : Date de naissance, population, genre, etc.
  • Structuration des Données : Organisent les informations de manière catégorique.

Wikidata: Informations, propriétés, qualifications et références

• Qualificatons :
  • Précision : Ajoutent des détails supplémentaires aux déclarations.
  • Exemples : Période pour une position occupée, lieu pour un événement, etc.
  • Affinement des Données : Améliorent la précision des informations.
• Références:
  • Source d'Information : Indiquent la provenance des données.
  • Citations et Liens : Incluent des références pour la vérification et la transparence.
  • Fondement de la Fidélité : Renforcent la crédibilité des informations.

Wikidata: Informations, propriétés, qualifications et références

Wikidata: External identifiers

Requêtes SPARQL

Requêtes SPARQL

Les identifiants des grandes villes.

SELECT ?grandeville WHERE {
  ?grandeville wdt:P31 wd:Q1549591.
}

SELECT ?grandeville WHERE {
  ?grandeville wdt:P31 wd:Q1549591.
}
LIMIT 100

Requêtes SPARQL

Les noms des grandes villes.

SELECT ?grandeville ?grandevilleLabel WHERE {
  ?grandeville wdt:P31 wd:Q1549591.
  SERVICE wikibase:label {
  bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 100

Requêtes SPARQL

Les noms des grandes villes dans différentes langues.

SELECT ?grandeville ?grandevilleLabel WHERE {
  ?grandeville wdt:P31 wd:Q1549591.
  ?grandeville rdfs:label ?grandevilleLabel.
}
LIMIT 100

Requêtes SPARQL

Les noms français des grandes villes.

SELECT ?grandeville ?grandevilleLabel WHERE {
  ?grandeville wdt:P31 wd:Q1549591;
    rdfs:label ?grandevilleLabel.
  FILTER(lang(?grandevilleLabel) = "fr")
}
LIMIT 100

Rémarque: Le sujet n'est pas répété sur la deuxième ligne grâce au point-virgule.

Requêtes SPARQL

Les noms des grandes villes de France.

SELECT ?grandeville ?grandevilleLabel WHERE {
  ?grandeville wdt:P31 wd:Q1549591;
    wdt:P17 wd:Q142;
    rdfs:label ?grandevilleLabel.
  FILTER(lang(?grandevilleLabel) = "fr")
}
LIMIT 100

Requêtes SPARQL

Les noms et images des grandes villes de France.

SELECT ?grandeville ?grandevilleLabel ?image {
  ?grandeville wdt:P31 wd:Q1549591;
               wdt:P17 wd:Q142;
               wdt:P18 ?image;
               rdfs:label ?grandevilleLabel.
  FILTER(lang(?grandevilleLabel) = "fr")
}

Requêtes SPARQL

Les noms et images des grandes villes.

SELECT DISTINCT ?grandeville ?grandevilleLabel ?pays ?paysLabel ?image {
  ?grandeville wdt:P31 wd:Q1549591;
               wdt:P17 ?pays;
               wdt:P18 ?image.
 SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
LIMIT 100

Requêtes SPARQL

Les noms de 100 langages de programmation.

SELECT ?languageLabel (YEAR(?inception) AS ?year) WHERE {
  ?language wdt:P31 wd:Q9143;
    wdt:P571 ?inception;
    rdfs:label ?languageLabel.
  FILTER((LANG(?languageLabel)) = "en")
}
ORDER BY (?year)
LIMIT 100

Requêtes SPARQL

Les noms de 100 langages de programmation et leurs paradigmes.

SELECT ?languageLabel ?paradigmLabel (YEAR(?inception) AS ?year) WHERE {
  ?language wdt:P31 wd:Q9143;
    wdt:P571 ?inception;
    wdt:P3966 ?paradigm;
    rdfs:label ?languageLabel.
  ?paradigm rdfs:label ?paradigmLabel.
  FILTER(((LANG(?languageLabel)) = "en") && ((LANG(?paradigmLabel)) = "en"))
}
ORDER BY (?year) (?paradigmLabel)
LIMIT 100

Requêtes SPARQL

Les informations disponibles sur la population des différents pays à différentes périodes.

SELECT DISTINCT ?countryLabel (YEAR(?date) AS ?year) ?population WHERE {
  ?country wdt:P31 wd:Q6256;
    p:P1082 ?populationStatement;
    rdfs:label ?countryLabel.
  ?populationStatement ps:P1082 ?population;
    pq:P585 ?date.
  FILTER((LANG(?countryLabel)) = "en")
}
ORDER BY (?countryLabel) (?year)
LIMIT 1000

Ressources en ligne

• Resource Description Framework (RDF) https://www.w3.org/RDF/
• Resource Description Framework https://en.wikipedia.org/wiki/Resource_Description_Framework

Couleurs

• Color Tool - Material Design

Images

• Wikimedia Commons