Traitement de données massives

Données ouvertes liées (Linked Open Data)

John Samuel
CPE Lyon

Année: 2024-2025
Courriel: john.samuel@cpe.fr

Linked Open Data

Linked Open Data

Linked Open Data

1. https://commons.wikimedia.org/wiki/File:Lod-datasets_2009-07-14.svg
2. https://commons.wikimedia.org/wiki/File:Lod-datasets_2010-09-22_colored.png

Wikidata

Wikidata a été lancé en 2012 en tant que projet collaboratif visant à créer une base de connaissances structurée et liée. Wikidata est une base de connaissances libre, ouverte, liée, structurée, collaborative et multilingue.

• Libre et Ouverte : Les données de Wikidata sont disponibles librement et ouvertement.
• Liée et Structurée : Les informations sont interconnectées et structurées selon le modèle RDF.
• Collaborative : Des contributeurs du monde entier ajoutent et éditent des données.
• Multilingue : Supporte plusieurs langues pour favoriser l'inclusivité.

Wikidata

Évolution des sites Wikipédia : de sites Wikipédia multilingues avec plusieurs sous-domaines à un site Wikidata multilingue avec un seul domaine.

Wikipédia: Articles multilingues

L'Infobox est une composante clé des articles Wikipédia. Elle fournit un résumé structuré et concis des informations essentielles sur un sujet.

• Contenu de l'Infobox :
  • Informations essentielles : Inclut des détails clés tels que la date de naissance, la localisation, les statistiques, etc.
  • Liens pertinents : Souvent liée à des entités pertinentes sur Wikidata.
• Objectifs de l'Infobox :
  • Accessibilité rapide : Facilite l'accès rapide aux faits importants.
  • Uniformité : Maintient une structure uniforme à travers les articles.
• Évolution dynamique :
  • Mise à jour collaborative : Peut être mis à jour de manière collaborative par la communauté Wikipédia.
  • Liens dynamiques avec Wikidata : Les liens peuvent être dynamiquement liés aux données de Wikidata pour une mise à jour centralisée.

Wikipédia: Articles multilingues

Problèmes potentiels

Wikipédia: Articles multilingues

Problèmes potentiels

• Possibilité de redondances entre les détails dans l'Infobox et le corps de l'article.
• La maintenance coordonnée des Infoboxes sur différentes Wikipédias peut être complexe.
• Difficulté à réaliser des mises à jour centralisées pour toutes les versions linguistiques.

Élément de Wikidata: libellés, descriptions et alias

Les éléments de Wikidata comprennent des libellés (labels), des descriptions et des alias. Les libellés sont les noms principaux, multilingues, attribués à chaque entité. Les descriptions fournissent des informations brèves sur la nature ou la signification de l'élément, tandis que les alias sont des synonymes ou variantes utilisés pour faciliter la recherche.

Élément (item) de Wikidata: Étiquettes et propriétés

Les propriétés définissent les caractéristiques ou relations des éléments. Exemples : Date de naissance, lieu de naissance, genre, etc. Elles permettent une structuration précise des informations liées aux éléments.

Propriétés de Wikidata

Propriétés: Étiquettes et descriptions

Propriétés

Propriétés de l'Infobox de Wikipedia

Identifiant, étiquettes, descriptions et alias

Wikidata: Informations, propriétés, qualifications et références

• Informations de Base :
  • Élément : Représente une entité dans Wikidata (personne, lieu, concept, etc.).
  • Identificateur Unique (QID) : Chaque élément est associé à un identifiant unique.
• Propriétés:
  • Définition : Caractéristiques ou relations spécifiques à un élément.
  • Exemples : Date de naissance, population, genre, etc.
  • Structuration des Données : Organisent les informations de manière catégorique.

Wikidata: Informations, propriétés, qualifications et références

• Qualificatons :
  • Précision : Ajoutent des détails supplémentaires aux déclarations.
  • Exemples : Période pour une position occupée, lieu pour un événement, etc.
  • Affinement des Données : Améliorent la précision des informations.
• Références:
  • Source d'Information : Indiquent la provenance des données.
  • Citations et Liens : Incluent des références pour la vérification et la transparence.
  • Fondement de la Fidélité : Renforcent la crédibilité des informations.

Wikidata: Informations, propriétés, qualifications et références

Wikidata: External identifiers

Requêtes SPARQL

Requêtes SPARQL

Les identifiants des grandes villes.

SELECT ?grandeville WHERE {
  ?grandeville wdt:P31 wd:Q1549591.
}

SELECT ?grandeville WHERE {
  ?grandeville wdt:P31 wd:Q1549591.
}
LIMIT 100

Requêtes SPARQL

Les noms des grandes villes.

SELECT ?grandeville ?grandevilleLabel WHERE {
  ?grandeville wdt:P31 wd:Q1549591.
  SERVICE wikibase:label { 
  bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
LIMIT 100

Requêtes SPARQL

Les noms des grandes villes dans différentes langues.

SELECT ?grandeville ?grandevilleLabel WHERE {
  ?grandeville wdt:P31 wd:Q1549591.
  ?grandeville rdfs:label ?grandevilleLabel.
}
LIMIT 100

Requêtes SPARQL

Les noms français des grandes villes.

SELECT ?grandeville ?grandevilleLabel WHERE {
  ?grandeville wdt:P31 wd:Q1549591;
    rdfs:label ?grandevilleLabel.
  FILTER(lang(?grandevilleLabel) = "fr")
}
LIMIT 100

Rémarque: Le sujet n'est pas répété sur la deuxième ligne grâce au point-virgule.

Requêtes SPARQL

Les noms des grandes villes de France.

SELECT ?grandeville ?grandevilleLabel WHERE {
  ?grandeville wdt:P31 wd:Q1549591;
    wdt:P17 wd:Q142;
    rdfs:label ?grandevilleLabel.
  FILTER(lang(?grandevilleLabel) = "fr")
}
LIMIT 100

Requêtes SPARQL

Les noms et images des grandes villes de France.

SELECT ?grandeville ?grandevilleLabel ?image {
  ?grandeville wdt:P31 wd:Q1549591;
               wdt:P17 wd:Q142;
               wdt:P18 ?image;
               rdfs:label ?grandevilleLabel.
  FILTER(lang(?grandevilleLabel) = "fr")
}

Requêtes SPARQL

Les noms et images des grandes villes.

SELECT DISTINCT ?grandeville ?grandevilleLabel ?pays ?paysLabel ?image {
  ?grandeville wdt:P31 wd:Q1549591;
               wdt:P17 ?pays;
               wdt:P18 ?image.
 SERVICE wikibase:label { bd:serviceParam wikibase:language "fr". }
}
LIMIT 100

Requêtes SPARQL

Les noms de 100 langages de programmation.

SELECT ?languageLabel (YEAR(?inception) AS ?year) WHERE {
  ?language wdt:P31 wd:Q9143;
    wdt:P571 ?inception;
    rdfs:label ?languageLabel.
  FILTER((LANG(?languageLabel)) = "en")
}
ORDER BY (?year)
LIMIT 100

Requêtes SPARQL

Les noms de 100 langages de programmation et leurs paradigmes.

SELECT ?languageLabel ?paradigmLabel (YEAR(?inception) AS ?year) WHERE {
  ?language wdt:P31 wd:Q9143;
    wdt:P571 ?inception;
    wdt:P3966 ?paradigm;
    rdfs:label ?languageLabel.
  ?paradigm rdfs:label ?paradigmLabel.
  FILTER(((LANG(?languageLabel)) = "en") && ((LANG(?paradigmLabel)) = "en"))
}
ORDER BY (?year) (?paradigmLabel)
LIMIT 100

Requêtes SPARQL

Les informations disponibles sur la population des différents pays à différentes périodes.

SELECT DISTINCT ?countryLabel (YEAR(?date) AS ?year) ?population WHERE {
  ?country wdt:P31 wd:Q6256;
    p:P1082 ?populationStatement;
    rdfs:label ?countryLabel.
  ?populationStatement ps:P1082 ?population;
    pq:P585 ?date.
  FILTER((LANG(?countryLabel)) = "en")
}
ORDER BY (?countryLabel) (?year)
LIMIT 1000

Ressources en ligne

• Resource Description Framework (RDF) https://www.w3.org/RDF/
• Resource Description Framework https://en.wikipedia.org/wiki/Resource_Description_Framework

Couleurs

• Color Tool - Material Design

Images

• Wikimedia Commons