• Wikidata
  • 85,000
  • destop applications
  • research software
  • FLOSS

• Wikidata
  • Inspired by WikiGenomes
  • Streamlined interface
  • Property checklists tailored to digital preservation
  • Specialty searches (PUID, mimetype)

• Development Team
  • Kenneth Seals-Nutt: software engineer
  • Katherine Thornton: Data curation, data models, SPARQL queries
  • Carl Wilson: technical mentor
  • Euan Cochrane: digital preservation program of work

• About 5,000 properties in Wikidata
• Data models are not pre-defined
• Portal has a domain-specific property checklist

• Python
• Flask
• SPARQL
• Wikidata Integrator
• MediaWiki API

• WDProp
  • Get real-time translation statistics
  • Navigate supported languages, properties, datatypes, classes
  • Compare translation statistics
  • Find available properties for an entity
  • Uses Wikidata SPARQL endpoints and Mediawiki API
• URL
  • https://tools.wmflabs.org/wdprop

• Digital Heritage
  • Wikidata: Multilingual, Structured Knowledge Base
  • Need for Digital Preservation
  • Digital Preservation on Wikidata
  • Community participation: Property proposition, translation and item description
  • Tools using SPARQL endpoints and/or MediaWiki API

• Tools
  • Wikidata SPARQL query endpoint
  • MediaWiki API
  • Wikidata Integrator
  • Histropedia
  • wdtaxonomy
  • WDProp
  • WikiDP
  • WikiDP Portal (Github)

• WikiProjects
  • WikiProjects
  • WikiProject Informatics
  • WikiProject Informatics/Programming Language
  • WikiProject Informatics/Software/Properties
  • WikiProject Informatics/Operating System

Programming paradigms with the count of programming languages

SELECT ?paradigmLabel (count(?prog) as ?count)
{
  ?prog wdt:P31 wd:Q9143;
        wdt:P3966 ?paradigm.
  SERVICE wikibase:label { bd:serviceParam
          wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP by ?paradigmLabel
HAVING (?count>1)
          

Programming languages with the count of programming paradigm

SELECT ?progLabel (count(?paradigm) as ?count)
{
  ?prog wdt:P31 wd:Q9143;
        wdt:P3966 ?paradigm.
  SERVICE wikibase:label { bd:serviceParam
          wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP by ?progLabel
HAVING (?count>2)
          

Programming languages with the count of multilingual labels

SELECT ?languageLabel (count(?label) as ?count) {
  {
    SELECT DISTINCT ?languageLabel ?label (lang(?label) as ?langLabel) {
      ?language wdt:P31/wdt:P279* wd:Q9143;
                rdfs:label ?label.
      SERVICE wikibase:label { bd:serviceParam
          wikibase:language "[AUTO_LANGUAGE],en". }
      }
  }

}
GROUP by ?languageLabel
HAVING (?count > 50)
ORDER by DESC(?count)

          

Software with the count of multilingual labels

SELECT ?softwareLabel (count(?label) as ?count) {
  {
    SELECT DISTINCT ?softwareLabel ?label (lang(?label) as ?langLabel) {
      ?software wdt:P31/wdt:P279 wd:Q7397;
                rdfs:label ?label.
      SERVICE wikibase:label { bd:serviceParam
          wikibase:language "[AUTO_LANGUAGE],en". }
      }
  }

}
GROUP by ?softwareLabel
HAVING (?count > 40)
ORDER by DESC(?count)

          

Programming language with the count of multilingual labels

SELECT ?langLabel (count(?language) as ?count) {
  {
    SELECT DISTINCT (lang(?label) as ?langLabel) ?language {
      ?language wdt:P31/wdt:P279* wd:Q9143;
                rdfs:label ?label.
      }
  }

}
GROUP by ?langLabel
ORDER by DESC(?count)

          

Language with the count of software labels

SELECT ?langLabel (count(?software) as ?count) {
  {
    SELECT DISTINCT (lang(?label) as ?langLabel) ?software {
      ?software wdt:P31/wdt:P279* wd:Q7397;
                rdfs:label ?label.
      }
  }

}
GROUP by ?langLabel
ORDER by DESC(?count)
          

Languages with the count of Wikipedia articles on programming languages

SELECT DISTINCT ?languageLabel ?sitelinks {
      ?language wdt:P31/wdt:P279* wd:Q9143;
                wikibase:sitelinks ?sitelinks.
       FILTER(?sitelinks > 20)
       SERVICE wikibase:label { bd:serviceParam
          wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER by DESC(?sitelinks)

          

Languages with the count of Wikipedia articles on software

SELECT DISTINCT ?softwareLabel ?sitelinks {
      ?software wdt:P31/wdt:P279* wd:Q7397;
                wikibase:sitelinks ?sitelinks.
       FILTER(?sitelinks > 100)
       SERVICE wikibase:label { bd:serviceParam
          wikibase:language "[AUTO_LANGUAGE],en". }
}
ORDER by DESC(?sitelinks)

          

Languages with the count of Wikipedia articles on programming languages

SELECT ?lang (count(?progLanguage) as ?count) {
  {
    SELECT DISTINCT ?progLanguage ?lang {
      ?progLanguage wdt:P31/wdt:P279* wd:Q9143.
      [] schema:about ?progLanguage;
         schema:inLanguage ?lang.
     }
  }
}
GROUP BY ?lang
ORDER BY DESC(?count)
          

Languages with the count of Wikipedia articles on Software

SELECT ?lang (count(?software) as ?count) {
  {
    SELECT DISTINCT ?software ?lang {
      ?software wdt:P31/wdt:P279* wd:Q7397.
      [] schema:about ?software;
         schema:inLanguage ?lang.
     }
  }
}
GROUP BY ?lang
ORDER BY DESC(?count)
          

Licenses approved by the Free Software Foundation by count of software titles available under each

SELECT ?item ?itemLabel (COUNT(DISTINCT ?software) AS ?count) WHERE {
  ?software (wdt:P31/wdt:P279*) wd:Q7397.
  ?software wdt:P275 ?item.
  ?item wdt:P790 wd:Q48413.
  SERVICE wikibase:label { bd:serviceParam
          wikibase:language "[AUTO_LANGUAGE],en". }
}
GROUP BY ?item ?itemLabel
ORDER BY DESC(?count)
          

UNIX utilities with identifiers in the LoC Name Authority File or in the GND

SELECT ?item ?itemLabel ?LCNAF ?GND
WHERE
{
  ?item wdt:P31 wd:Q18343316.
  OPTIONAL {?item wdt:P244 ?LCNAF}.
  OPTIONAL {?item wdt:P227 ?GND}.
  SERVICE wikibase:label { bd:serviceParam
          wikibase:language "[AUTO_LANGUAGE],en". }
}
          

Software developed by members of Deutsches Forschungsnetz

SELECT ?member ?memberLabel ?software ?softwareLabel WHERE {
  ?member wdt:P463 wd:Q2514863.
  ?software wdt:P178 ?member.
  SERVICE wikibase:label { bd:serviceParam
          wikibase:language "[AUTO_LANGUAGE],en". }
}